Restore pre-IPv6 localip_update() code for systems without ifaddrs.h
[darkstat] / configure.ac
1 AC_INIT(darkstat, 3.0.0-git, , , http://unix4lyfe.org/darkstat/)
2 AC_CONFIG_SRCDIR([darkstat.c])
3 AC_CONFIG_HEADER([config.h])
4
5 RULE="------------------------------------------------------------"
6
7 # Let user specify CHROOT_DIR, or else autodetect it, or else die.
8 AC_ARG_WITH(chroot-dir, AS_HELP_STRING([--with-chroot-dir],
9  [specify the chroot directory (default: /var/empty)]),
10  [if test "x$withval" = "xyes"; then
11    AC_MSG_ERROR([please specify --with-chroot-dir=/path/to/darkstat/chroot])
12   fi
13   _chd="$withval"],
14  [# Find an "empty" directory to serve as the chroot.
15   _chd="/var/empty"
16   AC_MSG_CHECKING([for $_chd])
17   if test -d $_chd ; then
18    AC_MSG_RESULT(found it)
19   else
20    AC_MSG_RESULT(not there)
21    _chd="/var/lib/empty"
22    AC_MSG_CHECKING([for $_chd])
23    if test -d $_chd ; then
24     AC_MSG_RESULT(found it)
25    else
26     AC_MSG_RESULT(not there either)
27     AC_MSG_ERROR([please specify --with-chroot-dir=/path/to/darkstat/chroot])
28    fi
29   fi])
30 AC_DEFINE_UNQUOTED(CHROOT_DIR, "$_chd", [Default chroot directory.])
31
32 # Allow configure-time override of PRIVDROP_USER.
33 AC_ARG_WITH(privdrop-user, AS_HELP_STRING([--with-privdrop-user],
34  [specify which user to drop privileges to (default: nobody)]),
35  [_pdu="$withval"],
36  [_pdu="nobody"])
37 AC_DEFINE_UNQUOTED(PRIVDROP_USER, "$_pdu", [User to privdrop to.])
38
39 # Checks for programs.
40 AC_PROG_INSTALL
41 AC_PROG_CC
42
43 m4_pattern_allow([^AM_DEFAULT_VERBOSITY$])
44 AC_ARG_ENABLE([silent-rules],
45 [  --enable-silent-rules          less verbose build output (undo: 'make V=1')
46   --disable-silent-rules         verbose build output (undo: 'make V=0')])
47 case $enable_silent_rules in
48 no)  AM_DEFAULT_VERBOSITY=1;;
49 *)   AM_DEFAULT_VERBOSITY=0;;
50 esac
51 AC_SUBST([AM_DEFAULT_VERBOSITY])
52
53 # Let user disable debugging symbols so we create smaller binaries.
54 AC_MSG_CHECKING(if we want debug code)
55 AC_ARG_ENABLE(debug, AS_HELP_STRING([--disable-debug],
56  [turn off debugging code and asserts]),
57  [if test "x$enableval" = "xno" ; then
58    CFLAGS="$CFLAGS -DNDEBUG -g0"
59    AC_MSG_RESULT(nope)
60   elif test "x$enableval" = "xyes" ; then
61    AC_MSG_RESULT(sure)
62   else
63    CFLAGS="$CFLAGS -g$enableval"
64    AC_MSG_RESULT(sure ($enableval))
65   fi],
66  [AC_MSG_RESULT(sure)])
67
68 # Augment CFLAGS for fun.
69 echo "int main(void){return 1;}" > conftest.$ac_ext
70
71 AC_MSG_CHECKING(if your C compiler wants a hit off the pipe)
72 save_cflags="$CFLAGS"
73 CFLAGS="-pipe $CFLAGS"
74 if (eval $ac_link) 2>/dev/null; then
75  AC_MSG_RESULT(sure does)
76 else
77  AC_MSG_RESULT(no)
78  CFLAGS="$save_cflags"
79 fi
80
81 AC_MSG_CHECKING(if your C compiler has a link-time optimizer)
82 if test x$GCC = xyes; then
83  save_cflags="$CFLAGS"
84  CFLAGS="-flto $CFLAGS"
85  if (eval $ac_link) 2>/dev/null; then
86   AC_MSG_RESULT(sure does)
87  else
88   AC_MSG_RESULT(no)
89   CFLAGS="$save_cflags"
90  fi
91 else
92  AC_MSG_RESULT(skipped)
93 fi
94
95 AC_ARG_ENABLE(mad-warnings, AS_HELP_STRING([--enable-mad-warnings],
96  [turn on lots of compile-time warnings, this needs GCC and is only
97  really useful for development]),
98  [if test "x$enableval" = "xyes" ; then
99    AC_MSG_CHECKING(if your C compiler throws mad warnings)
100    save_cflags="$CFLAGS"
101    CFLAGS="$CFLAGS -fdiagnostics-show-option \
102 -Wabi \
103 -Waddress \
104 -Waggregate-return \
105 -Wall \
106 -Warray-bounds \
107 -Wbad-function-cast \
108 -Wcast-align \
109 -Wcast-qual \
110 -Wchar-subscripts \
111 -Wclobbered \
112 -Wcomment \
113 -Wcoverage-mismatch \
114 -Wdeclaration-after-statement \
115 -Wdisabled-optimization \
116 -Wempty-body \
117 -Wextra \
118 -Wfloat-equal \
119 -Wformat \
120 -Wformat=2 \
121 -Wformat-nonliteral \
122 -Wformat-security \
123 -Wformat-y2k \
124 -Wignored-qualifiers \
125 -Wimplicit \
126 -Wimplicit-function-declaration \
127 -Wimplicit-int \
128 -Winit-self \
129 -Winline \
130 -Winvalid-pch \
131 -Wlogical-op \
132 -Wlong-long \
133 -Wmain \
134 -Wmissing-braces \
135 -Wmissing-declarations \
136 -Wmissing-field-initializers \
137 -Wmissing-format-attribute \
138 -Wmissing-include-dirs \
139 -Wmissing-noreturn \
140 -Wmissing-parameter-type \
141 -Wmissing-prototypes \
142 -Wnested-externs \
143 -Wnonnull \
144 -Wold-style-declaration \
145 -Wold-style-definition \
146 -Wpacked \
147 -Wpacked-bitfield-compat \
148 -Wparentheses \
149 -Wpointer-arith \
150 -Wpointer-sign \
151 -Wredundant-decls \
152 -Wreturn-type \
153 -Wsequence-point \
154 -Wshadow \
155 -Wsign-compare \
156 -Wstrict-aliasing -fstrict-aliasing \
157 -Wstrict-overflow=5 -fstrict-overflow \
158 -Wstrict-prototypes \
159 -Wswitch \
160 -Wswitch-default \
161 -Wswitch-enum \
162 -Wsync-nand \
163 -Wtrigraphs \
164 -Wtype-limits \
165 -Wundef \
166 -Wuninitialized \
167 -Wunknown-pragmas \
168 -Wunsafe-loop-optimizations \
169 -Wunused \
170 -Wunused-function \
171 -Wunused-label \
172 -Wunused-parameter \
173 -Wunused-value \
174 -Wunused-variable \
175 -Wvariadic-macros \
176 -Wvla \
177 -Wvolatile-register-var \
178 -Wwrite-strings \
179 "
180
181 # the above are valid for gcc version 4.4.3
182 # we skip:
183 #-pedantic
184 #-Wc++-compat
185 #-Wconversion
186 #-Wfatal-errors
187 #-Wpadded
188 #-Wsign-conversion
189 #-Wstack-protector
190 #-Wsystem-headers
191 #-Wtraditional
192 #-Wtraditional-conversion
193 #-Wunreachable-code
194
195    if (eval $ac_link) 2>/dev/null; then
196     AC_MSG_RESULT(sure does)
197    else
198     AC_MSG_RESULT(no)
199     CFLAGS="$save_cflags"
200    fi
201   fi])
202
203 rm -f conftest.$ac_objext conftest.$ac_ext
204
205
206
207 # Check for zlib.
208 AC_CHECK_LIB(z, deflate,, [
209  cat <<END
210 $RULE
211
212 I can't link to zlib.  You really can't have a modern
213 operating system without zlib.
214
215 If you are using a package-based operating system (like
216 something with RPMs), see if there is a zlib-devel package
217 that you can install, to provide the zlib headers and
218 libraries.
219
220 $RULE
221 END
222  AC_MSG_ERROR([can't find usable zlib])])
223
224
225
226 # Check for Solaris.
227 # Must do at least socket and nsl before checking for libpcap.
228 AC_SEARCH_LIBS(gethostbyname, [nsl], [],
229   [AC_MSG_ERROR([gethostbyname() not found])])
230 AC_SEARCH_LIBS(socket, [socket], [],
231   [AC_MSG_ERROR([socket() not found])])
232 AC_SEARCH_LIBS(inet_aton, [resolv], [],
233   [AC_MSG_ERROR([inet_aton() not found])])
234
235 # Solaris need sys/filio.h for FIONBIO
236 AC_CHECK_HEADERS(sys/filio.h)
237
238 # GNU/kfreebsd needs net/if_ether.h for ETH_P_IPV6
239 AC_CHECK_HEADERS(net/if_ether.h)
240
241 # This is the modern way.  Older systems use the ioctl method.
242 AC_CHECK_HEADERS(ifaddrs.h)
243
244 # Some OSes (Solaris) need sys/sockio.h for SIOCGIFADDR
245 AC_CHECK_HEADERS(sys/sockio.h)
246
247 # Check for libpcap
248 AC_ARG_WITH(pcap, AS_HELP_STRING([--with-pcap=DIR],
249  [prefix to libpcap installation]),
250  [if test "$withval" = yes ; then
251    AC_MSG_ERROR([must specify a path, as in --with-pcap=DIR])
252   fi
253   if test "$withval" != no ; then
254    PCAP_HOME="$withval"
255   fi])
256
257 if test -n "$PCAP_HOME" ; then
258  LDFLAGS="$LDFLAGS -L$PCAP_HOME/lib"
259  CPPFLAGS2="$CPPFLAGS -I$PCAP_HOME/include/pcap"
260  CPPFLAGS="$CPPFLAGS -I$PCAP_HOME/include"
261 else
262  CPPFLAGS2="$CPPFLAGS -I/usr/include/pcap"
263 fi
264
265 AC_CHECK_LIB(pcap, pcap_loop,, PCAP_BROKEN="yes")
266
267 if test -z "$PCAP_BROKEN" ; then
268   AC_CHECK_HEADERS(pcap.h,,
269   [# Couldn't find headers, try include/pcap
270    CPPFLAGS="$CPPFLAGS2"
271    AC_MSG_NOTICE([checking in include/pcap])
272    unset ac_cv_header_pcap_h
273    AC_CHECK_HEADERS(pcap.h,
274     AC_MSG_RESULT([I hate you.]),
275     PCAP_BROKEN="yes")])
276 fi
277
278 if test -n "$PCAP_BROKEN" ; then
279  cat <<END_MSG
280 $RULE
281
282 darkstat absolutely requires libpcap to be installed.  If
283 it's installed into a prefix that isn't being picked up by
284 configure, for example /usr/local, re-run configure and add
285 --with-pcap=/usr/local
286
287 If you are using a package-based operating system (like
288 something with RPMs), see if there is a pcap-devel or
289 libpcap-devel package that you can install, to provide the
290 pcap headers and libraries.
291
292 Failing all of the above, go to http://www.tcpdump.org/ and
293 download the source distribution of libpcap and build it
294 yourself.
295
296 $RULE
297 END_MSG
298  AC_MSG_ERROR([can't find usable libpcap])
299 fi
300
301
302
303 # A real OS will have setproctitle()
304 AC_SEARCH_LIBS(setproctitle, [bsd],
305  AC_DEFINE(HAVE_SETPROCTITLE, 1,
306   [Define to 1 if you have setproctitle().]))
307
308 # A real OS will have safe string functions
309 AC_SEARCH_LIBS(strlcpy, [bsd],
310  AC_DEFINE(HAVE_STRLCPY, 1,
311   [Define to 1 if you have strlcpy().]))
312
313 AC_SEARCH_LIBS(strlcat, [bsd],
314  AC_DEFINE(HAVE_STRLCAT, 1,
315   [Define to 1 if you have strlcat().]))
316
317
318 AC_CONFIG_FILES([Makefile darkstat.8])
319 AC_OUTPUT