Make configure --enable-warnings use {all,extra}-warnings with GCC.
[darkstat] / configure.ac
1 AC_INIT(darkstat, 3.0.0-git, , , http://unix4lyfe.org/darkstat/)
2 AC_CONFIG_SRCDIR([darkstat.c])
3 AC_CONFIG_HEADER([config.h])
4
5 RULE="------------------------------------------------------------"
6
7 # Let user specify CHROOT_DIR, or else autodetect it, or else die.
8 AC_ARG_WITH(chroot-dir, AS_HELP_STRING([--with-chroot-dir],
9  [specify the chroot directory (default: /var/empty)]),
10  [if test "x$withval" = "xyes"; then
11    AC_MSG_ERROR([please specify --with-chroot-dir=/path/to/darkstat/chroot])
12   fi
13   _chd="$withval"],
14  [# Find an "empty" directory to serve as the chroot.
15   _chd="/var/empty"
16   AC_MSG_CHECKING([for $_chd])
17   if test -d $_chd ; then
18    AC_MSG_RESULT(found it)
19   else
20    AC_MSG_RESULT(not there)
21    _chd="/var/lib/empty"
22    AC_MSG_CHECKING([for $_chd])
23    if test -d $_chd ; then
24     AC_MSG_RESULT(found it)
25    else
26     AC_MSG_RESULT(not there either)
27     AC_MSG_ERROR([please specify --with-chroot-dir=/path/to/darkstat/chroot])
28    fi
29   fi])
30 AC_DEFINE_UNQUOTED(CHROOT_DIR, "$_chd", [Default chroot directory.])
31
32 # Allow configure-time override of PRIVDROP_USER.
33 AC_ARG_WITH(privdrop-user, AS_HELP_STRING([--with-privdrop-user],
34  [specify which user to drop privileges to (default: nobody)]),
35  [_pdu="$withval"],
36  [_pdu="nobody"])
37 AC_DEFINE_UNQUOTED(PRIVDROP_USER, "$_pdu", [User to privdrop to.])
38
39 # Checks for programs.
40 AC_PROG_INSTALL
41 AC_PROG_CC
42
43 m4_pattern_allow([^AM_DEFAULT_VERBOSITY$])
44 AC_ARG_ENABLE([silent-rules],
45 [  --enable-silent-rules          less verbose build output (undo: 'make V=1')
46   --disable-silent-rules         verbose build output (undo: 'make V=0')])
47 case $enable_silent_rules in
48 no)  AM_DEFAULT_VERBOSITY=1;;
49 *)   AM_DEFAULT_VERBOSITY=0;;
50 esac
51 AC_SUBST([AM_DEFAULT_VERBOSITY])
52
53 # Let user disable debugging symbols so we create smaller binaries.
54 AC_MSG_CHECKING(if we want debug code)
55 AC_ARG_ENABLE(debug, AS_HELP_STRING([--disable-debug],
56  [turn off debugging code and asserts]),
57  [if test "x$enableval" = "xno" ; then
58    CFLAGS="$CFLAGS -DNDEBUG -g0"
59    AC_MSG_RESULT(nope)
60   elif test "x$enableval" = "xyes" ; then
61    AC_MSG_RESULT(sure)
62   else
63    CFLAGS="$CFLAGS -g$enableval"
64    AC_MSG_RESULT(sure ($enableval))
65   fi],
66  [AC_MSG_RESULT(sure)])
67
68 # Augment CFLAGS for fun.
69 echo "int main(void){return 1;}" > conftest.$ac_ext
70
71 AC_MSG_CHECKING(if your C compiler wants a hit off the pipe)
72 save_cflags="$CFLAGS"
73 CFLAGS="-pipe $CFLAGS"
74 if (eval $ac_link) 2>/dev/null; then
75  AC_MSG_RESULT(sure does)
76 else
77  AC_MSG_RESULT(no)
78  CFLAGS="$save_cflags"
79 fi
80
81 AC_MSG_CHECKING(if your C compiler has a link-time optimizer)
82 if test x$GCC = xyes; then
83  save_cflags="$CFLAGS"
84  CFLAGS="-flto $CFLAGS"
85  if (eval $ac_link) 2>/dev/null; then
86   AC_MSG_RESULT(sure does)
87  else
88   AC_MSG_RESULT(no)
89   CFLAGS="$save_cflags"
90  fi
91 else
92  AC_MSG_RESULT(skipped)
93 fi
94
95 AC_ARG_ENABLE(warnings, AS_HELP_STRING([--enable-warnings],
96  [turn on lots of compile-time warnings,
97   these are only useful for development]),
98  [if test "x$enableval" = "xyes" ; then
99    AC_MSG_CHECKING(if your C compiler has gcc-like --extra-warnings)
100    save_cflags="$CFLAGS"
101    CFLAGS="$CFLAGS -fdiagnostics-show-option --all-warnings --extra-warnings"
102    if (eval $ac_link) 2>/dev/null; then
103     AC_MSG_RESULT(yes)
104    else
105     AC_MSG_RESULT(no)
106     CFLAGS="$save_cflags"
107    fi
108
109    AC_MSG_CHECKING(if your C compiler has clang-like -Weverything)
110    save_cflags="$CFLAGS"
111    CFLAGS="$CFLAGS -Weverything"
112    if (eval $ac_link) 2>/dev/null; then
113     AC_MSG_RESULT(yes)
114    else
115     AC_MSG_RESULT(no)
116     CFLAGS="$save_cflags"
117    fi
118   fi])
119
120 rm -f conftest.$ac_objext conftest.$ac_ext
121
122
123
124 # Check for zlib.
125 AC_CHECK_LIB(z, deflate,, [
126  cat <<END
127 $RULE
128
129 I can't link to zlib.  You really can't have a modern
130 operating system without zlib.
131
132 If you are using a package-based operating system (like
133 something with RPMs), see if there is a zlib-devel package
134 that you can install, to provide the zlib headers and
135 libraries.
136
137 $RULE
138 END
139  AC_MSG_ERROR([can't find usable zlib])])
140
141
142
143 # Check for Solaris.
144 # Must do at least socket and nsl before checking for libpcap.
145 AC_SEARCH_LIBS(gethostbyname, [nsl], [],
146   [AC_MSG_ERROR([gethostbyname() not found])])
147 AC_SEARCH_LIBS(socket, [socket], [],
148   [AC_MSG_ERROR([socket() not found])])
149 AC_SEARCH_LIBS(hstrerror, [resolv], [],
150   [AC_MSG_ERROR([hstrerror() not found])])
151
152 # Solaris need sys/filio.h for FIONBIO
153 AC_CHECK_HEADERS(sys/filio.h)
154
155 # This is the modern way.  Older systems use the ioctl method.
156 AC_CHECK_HEADERS(ifaddrs.h)
157
158 # Some OSes (Solaris) need sys/sockio.h for SIOCGIFADDR
159 AC_CHECK_HEADERS(sys/sockio.h)
160
161 # Check for libpcap
162 AC_ARG_WITH(pcap, AS_HELP_STRING([--with-pcap=DIR],
163  [prefix to libpcap installation]),
164  [if test "$withval" = yes ; then
165    AC_MSG_ERROR([must specify a path, as in --with-pcap=DIR])
166   fi
167   if test "$withval" != no ; then
168    PCAP_HOME="$withval"
169   fi])
170
171 if test -n "$PCAP_HOME" ; then
172  LDFLAGS="$LDFLAGS -L$PCAP_HOME/lib"
173  CPPFLAGS2="$CPPFLAGS -I$PCAP_HOME/include/pcap"
174  CPPFLAGS="$CPPFLAGS -I$PCAP_HOME/include"
175 else
176  CPPFLAGS2="$CPPFLAGS -I/usr/include/pcap"
177 fi
178
179 AC_CHECK_LIB(pcap, pcap_loop,, PCAP_BROKEN="yes")
180
181 if test -z "$PCAP_BROKEN" ; then
182   AC_CHECK_HEADERS(pcap.h,,
183   [# Couldn't find headers, try include/pcap
184    CPPFLAGS="$CPPFLAGS2"
185    AC_MSG_NOTICE([checking in include/pcap])
186    unset ac_cv_header_pcap_h
187    AC_CHECK_HEADERS(pcap.h,
188     AC_MSG_RESULT([I hate you.]),
189     PCAP_BROKEN="yes")])
190 fi
191
192 if test -n "$PCAP_BROKEN" ; then
193  cat <<END_MSG
194 $RULE
195
196 darkstat absolutely requires libpcap to be installed.  On Debian
197 systems, apt-get install libpcap-dev.  On RPM systems like RedHat, try
198 installing the libpcap-devel package.
199
200 If libpcap is installed into a prefix that isn't being picked up by
201 configure, for example /usr/local, re-run configure and add
202 --with-pcap=/usr/local
203
204 Failing all of the above, go to http://www.tcpdump.org/ and download the
205 source distribution of libpcap and build it yourself.
206
207 $RULE
208 END_MSG
209  AC_MSG_ERROR([can't find usable libpcap])
210 fi
211
212 # If not in libc, we might find these in libbsd.
213 AC_SEARCH_LIBS(setproctitle, [bsd],
214  AC_DEFINE(HAVE_SETPROCTITLE, 1,
215   [Define to 1 if you have setproctitle().]))
216 AC_SEARCH_LIBS(strlcpy, [bsd],
217  AC_DEFINE(HAVE_STRLCPY, 1,
218   [Define to 1 if you have strlcpy().]))
219 AC_SEARCH_LIBS(strlcat, [bsd],
220  AC_DEFINE(HAVE_STRLCAT, 1,
221   [Define to 1 if you have strlcat().]))
222
223 AC_CHECK_HEADERS(bsd/string.h)
224 AC_CHECK_HEADERS(bsd/unistd.h)
225
226 AC_SEARCH_LIBS(clock_gettime, rt)
227
228 AC_CONFIG_FILES([Makefile darkstat.8])
229 AC_OUTPUT